Rem StarBasic macro pour/for StarOffice: ' A (execute macro) --> Á
Rem Compose toute lettre accentuée
Rem La macro doit être affectée à une touche (F6, ctrl-n, ...)

Rem Compose any accented letter
Rem The macro should be assigned to a key (F6, ctrl-n, ...)

Rem Logiciel libre.
Rem This macro is free software, you can use it as you like.
Rem  J.-P. Gallou gallou@cict.fr, 11 mar 2000
Rem mis a jour/updated  22 mar 2002
Rem <http://www.cict.fr/app/soffice/accentSO.html>

Dim l, ls, c As String

Sub Main
Dim s, lc As String
Selection.GoLeft( 2, TRUE )
s=Selection.Value
l=right (s, 1)
ls="aceinosuyzACEINOSUYZ"
c=""
Select Case left (s, 1)
Case "'", "’", "‘"
  MetAccent("á éí ó úý Á ÉÍ Ó ÚÝ ")
Case "`"
  MetAccent("à èì ò ù  À ÈÌ Ò Ù  ")
Case "^"
  MetAccent("âçêî ôšû žÂÇÊÎ ÔŠÛ Ž")
Case """", ":"
  MetAccent("ä ëï ö üÿ Ä ËÏ Ö ÜŸ ")
Case "~"
  MetAccent("ã   ñõ    Ã   ÑÕ    ")
Case else
  Select Case s
  Case "eu"
    c = "€"
  Case "mi", "mu"
    c = "µ"
  Case "ae"
    c = "æ"
  Case "AE"
    c = "Æ"
  Case "oe"
    c = "œ"
  Case "OE"
    c = "Œ"
  Case "sz"
    c = "ß"
  Case ".a", "°a"
    c = "å"
  Case ".A", "°A"
    c = "Å"
  Case "/o"
    c = "ø"
  Case "/O"
    c = "Ø"
  Case "pm", "pt"
    c = "‰"
  Case "tm"
    c = "™"
  Case "po"
    c = "£"
  Case "sp"
    c = " "
  Case "!!"
    c = "¡"
  Case "??"
    c = "¿"
  Case "mo"
    c = "¤"
  Case "ye"
    c = "¥"
  Case "se"
    c = "§"
  Case "pa"
    c = "¶"
  Case "co"
    c = "©"
  Case "re"
    c = "®"
  Case "ma"
    c = "¯"
  Case "no"
    c = "¬"
  Case "+-"
    c = "±"
  Case "xx"
    c = "×"
  Case "-n"
    c = "–"
  Case "-m"
    c = "—"
  Case ":-"
    c = "÷"
  Case ".."
    c = "…"
  Case "of"
    c = "ª"
  Case "om"
    c = "º"
  Case "e1", "s1"
    c = "¹"
  Case "e2", "s2"
    c = "²"
  Case "e3", "s3"
    c = "³"
  Case "14"
    c = "¼"
  Case "12"
    c = "½"
  Case "34"
    c = "¾"
  Case "ce"
    c = "¢"
  Case "et"
    c = "ð"
  Case "ET"
    c = "Ð"
  Case "th"
    c = "þ"
  Case "TH"
    c = "Þ"
  End Select
End Select 
if c = "" or c = " " then
  Selection.GoRight 2
Else 
  Selection.Backspace()
  Selection.Insert(c)
End If 
end sub

Function MetAccent(la as String)
Dim i As Integer
For i = 1 To 20
  if mid (ls, i, 1) = l then
    c = mid (la, i, 1)
    exit for
  end if
Next i
end Function